Comments

  // this is a comment

  Comments can be preceded by code on the same line.

Blocks

  {
    ...
  }

  The opening and closing braces must each be on their own line.

Assignment

  set variable value

Drawing

  paper t
    Clears the page with tone t, where t is a percentage of black from 0 to 100.
  pen t
    Sets the drawing tone to t, where t is a percentage of black from 0 to 100.
  line x0 y0 x1 y1
    Draws a line with the current drawing tone.
  [ x y ]
    An arithmetic expression equal to the current tone of the pixel at (x,y).
    Note that x and y are from 0 to 100.
  set [ x y ] t
    Sets the pixel at (x,y) to tone t, where t is a percentage of black from 0 to 100.

Loops

  repeat variable start_value end_value
  {
    ...
  }

  The end_value can be larger or smaller than the start_value.

  forever
  {
    ...
  }

  Forever loops are implicitly double buffered.
  A program can break out of a forever loop with the "escape" keyword.

Arithmetic Operators

  + - * /

  Multiplication and division take precedence.
  Arithmetic expressions formed with these operators
  must (usually) be enclosed in parentheses ( ).

Special Numbers

  <mouse n>
    n is 1 for x, 2 for y, 3 for button state (0 is not pressed, 100 is pressed)
  <key n>
    n is 1 to 26 for keyboard keys a-z.  State is 0 for not pressed, 100 for pressed.
  <time n>
    n is 1 for hours, 2 for minutes, 3 for seconds, 4 for hundredths.
  <net n>
    n is 1 to 1000.  These values are read/writable, and are globally shared by
    users of the system.  Not yet supported.

Equality

  same? expression1 expression2
  {
    ...
  }

  notsame? expression1 expression2
  {
    ...
  }

Inequality

  smaller? expression1 expression2
  {
    ...
  }

  notsmaller? expression1 expression2
  {
    ...
  }

Procedure and Function Definitions

  command procedure_name parameter1 parameter2 ... parameterN
  {
    // can read global variables if desired
    ...
  }

  number function_name parameter1 parameter2 ... parameterN
  {
    // can read global variables if desired
    ...
    value returnValue
  }

  To call a procedure, just do
    procedure_name argument1 ... argumentN

  To call a function, use angle brackets:
    <function_name argument1 ... argumentN>

Libraries

  load library_name.dbn

  load dbngraphics.dbn

    Defines
      circle x y radius tone
      rectangle x1 y1 x2 y2
      field x1 y1 x2 y2 tone
      triangle x1 y1 x2 y2 x3 y3

  load dbnletters.dbn

    Defines
      letter n x y  // n is 1 to 26

Examples:
======================================
repeat t 0 100
{
  pen t
  line 0 t t t
  line t 0 t t
}
======================================
load dbnletters.dbn
repeat x 0 4
{
  repeat y 0 4
  {
    set c (y*5+x+1)
    letter c (x*16+10) (y*16+10)
  }
}
letter 26 85 85
======================================
number zee t
{
  value (t+20)
}

repeat x 0 10
{
  line x 0 <zee x> 100
}
======================================
// concentric circles
load dbngraphics.dbn
paper 100
repeat r 1 50
{
  circle 50 50 r (r*2)
}